BODIK SPARQL API

共通フォーマットで公開されたデータの一部について、試験的にSPARQL APIを使ったデータの提供を行っています。

1.名称

名称:BODIK SPARQL API(以下、本API)

2.本API提供URL
3.語彙

本APIでは、以下の語彙を使ってRDF(Resource Description Framewrok)形式のデータを作成しています。

語彙 名前空間
共通語彙基盤 コア語彙V2 http://imi.go.jp/ns/core/rdf#
4.データモデル

RDF形式のデータの作成に用いるデータモデルは、政府CIOポータルのオープンデータページ(https://cio.go.jp/policy-opendata)で公開されている「推奨データセット一覧」のデータ項目定義書に準拠したデータモデルを用いています。

5.提供中のデータ

データはBODIK ODCS内で各団体により公開されたデータを元に作成しています。

データの種類 データに含まれる自治体
避難所・避難場所 北九州市、福岡市、久留米市、大川市、小郡市、筑紫野市、春日市、大野城市、宗像市、太宰府市、古賀市、福津市、うきは市、糸島市、那珂川市、宇美町、篠栗町、志免町、須恵町、新宮町、久山町、粕屋町、大刀洗町、大木町(団体コード順)
6.サンプルクエリ

クエリページ内で、SPARQLを使ったクエリによりデータを表示できます。

  1. 自治体名が福岡市の指定緊急避難場所名の一覧(25件まで)を表示
  2. PREFIX ic: <http://imi.go.jp/ns/core/rdf#>
    SELECT ?名前
    WHERE {
      ?s ic:関与/ic:関与者/ic:住所/ic:市区町村 "福岡市" ;
         ic:名称/ic:表記 ?名前 . 
    }
    LIMIT 25
    
  3. 自治体コードが402036の指定緊急避難場所名の一覧(25件まで)を表示
  4. PREFIX ic: <http://imi.go.jp/ns/core/rdf#>
    SELECT ?名前
    WHERE {
      ?s ic:関与/ic:関与者/ic:ID/ic:識別値 "402036" ;
         ic:名称/ic:表記 ?名前 . 
    }
    LIMIT 25
    
  5. 自治体コードが402036の指定緊急避難場所名、住所、緯度、経度の一覧(25件まで)を表示
  6. PREFIX ic: <http://imi.go.jp/ns/core/rdf#>
    SELECT ?名前 ?住所 ?緯度 ?経度
    WHERE {
      ?s ic:関与/ic:関与者/ic:ID/ic:識別値 "402036" ;
         ic:名称/ic:表記 ?名前 ; 
         ic:住所/ic:表記 ?住所 ;
         ic:地理座標/ic:緯度 ?緯度 ;
         ic:地理座標/ic:経度 ?経度 .
    }
    LIMIT 25
    
  7. データベース内の指定緊急避難で、全ての災害種別に対する対応一覧(25件まで)を表示
  8. PREFIX ic: <http://imi.go.jp/ns/core/rdf#>
    SELECT ?施設名 ?住所 ?種別 ?識別値
    WHERE {   
      ?s ic:関与/ic:関与者/ic:ID/ic:識別値 "401005" ;
         ic:名称/ic:表記 ?施設名 ;
         ic:住所/ic:表記 ?住所 ;
         ic:種別コード ?種別コード .
      ?種別コード ic:種別 ?種別 .
      ?種別コード ic:識別値 ?識別値 .
    }
    LIMIT 25
    
  9. 自治体コードが401005(北九州市)の指定緊急避難場所名で、「災害種別」が洪水に対応している施設名、住所の一覧(25件まで)を表示
  10. PREFIX ic: <http://imi.go.jp/ns/core/rdf#>
    SELECT ?施設名 ?住所 ?種別 ?識別値
    WHERE {   
      ?s ic:関与/ic:関与者/ic:ID/ic:識別値 "401005" ;
         ic:名称/ic:表記 ?施設名 ;
         ic:住所/ic:表記 ?住所 ;
         ic:種別コード ?種別コード .
      ?種別コード ic:種別 ?種別 .
      ?種別コード ic:識別値 ?識別値 .
      FILTER(?種別 = "災害種別_洪水") .
      FILTER(?識別値 = "1") .
    }
    LIMIT 25